&НаСервере
Процедура ВыполнитьКодНаСервере()
 
    /// Как получить и изменить значение константы в 1с 8.3, 8.2    
 
    // менеджер значений создаётся и используется неявно
 
    Сообщить(Константы.ЛучшийКлиент.Получить());
 
    Константы.ЛучшийКлиент.Установить(
        Справочники.Клиенты.НайтиПоНаименованию("Марина")
    );
 
    /// Работа с константой через менеджер значений в 1с 8.3, 8.2
 
    // создаём и используем менеджер значений константы напрямую
    ЛюбимаяЕда = Константы.ЛюбимаяЕда.СоздатьМенеджерЗначения();
 
    // читаем значение
    ЛюбимаяЕда.Прочитать();    
    Сообщить(ЛюбимаяЕда.Значение);
 
    // меняем значение
    ЛюбимаяЕда.Значение = Справочники.Еда.НайтиПоНаименованию(
        "Крыжовник");
 
    // записываем значение
    ЛюбимаяЕда.Записать();
 
    /// Работа с константами через набор в 1с 8.3, 8.2
 
    // подходит для работы сразу с группой констант
 
    НазванияКонстант = "ЛюбимаяЕда, ЛучшийКлиент";
    НаборКонстант = Константы.СоздатьНабор(НазванияКонстант);
 
    // читаем набор констант
    НаборКонстант.Прочитать();
    Сообщить(НаборКонстант.ЛюбимаяЕда);
    Сообщить(НаборКонстант.ЛучшийКлиент);
 
    // меняем значения констант
    НаборКонстант.ЛюбимаяЕда = Справочники.Еда.НайтиПоНаименованию(
        "Чипсы");
    НаборКонстант.ЛучшийКлиент = Справочники.Клиенты.НайтиПоНаименованию(
        "Пётр");
 
    // записываем набор
    НаборКонстант.Записать();
 
    /// Как получить значения всех констант в 1с 8.3, 8.2
 
    Для Каждого Константа Из Константы Цикл
        Сообщить(Строка(Константа) + " = " + Константа.Получить());
    КонецЦикла;
 
КонецПроцедуры
 
/// Скачать и выполнить эти примеры на компьютере